;--- Ридер PKT почты -----
;	(c) A. Lelikov

.MACRO	.OFF
	IOT
.ENDM
.MACRO	.ON
	.WORD -1
.ENDM
	;MKDOS const.
tst2	=120064
screen	=120074
DIR	=120014
dirfin	=120026
SUBTEK	=120010
BLK	=120006
INOUT	=120022
SAVDIR	=120042
DELETE	=120036

START:	MOV	#774,SP
	BR 52$
	JMP DSKR	; RW/ -Приоритет...

52$:	MOV	#PRCNF,R1
	;MOV	BLK,R0
	;MOVB	34(R0),R0
	;ADD	#'A,R0
	;MOVB	R0,6(R1)
	EMT	36
	TSTB	1(R1)
	BEQ	1$
	HALT
1$:	MOV	#fremem,r3
	JSR	r5,sear
	.word	kluj
	CLR	R3
3$:	movb	(r4)+,r0
	BEQ	4$
	call	@tst2
	cmpb	r0,#'F
	beq	2$
	BR	3$
4$:	COM	r3
2$:	mov	r3,(pc)+
klf::	.word	0			;0-КЛУДЖИ НЕ ПОКАЗЫВАТЬ.
	JSR PC,WINIT
	JSR PC,LINIT
	MOV #"00,MSVN
	JSR R0,TBLK
	.WORD TXT0,40000,41200,41200
	.WORD 100,42400,41400,354	; Копирование.
	.WORD TXT1,76600,0
;------ Создание списка файлов -------

STR2:	MOV #-1,(PC)+
KOLFIL::.WORD 0
	mov	#txt91,306
	mov	dir,r3
	jsr	PC,@dirfin
	bcs	1$
	movb	(r3),r0
	mov	r0,pdkt
1$:	MOV	#FREMEM+2000,R1
	mov	dir,r3
	mov	30(r3),r4
	add	#500-30,r3
2$:	add	#30,r3
	cmpb	(r3),#377
	beq	2$
	bit	#100000,22(r3)
	beq	3$
	jsr	pc,10$
3$:	sob	r4,2$
	tst	koLfil
	bpl	5$

	mov	dir,r3
	mov	30(r3),r4
	add	#500-30,r3
6$:	add	#30,r3
	cmpb	(r3),#377
	beq	6$
	jsr	pc,10$
	sob	r4,6$
	tst	kolfil
	bpl	5$
	JMP	@#100000
10$:	JSR	R5,EXT
	.asciz/PKT/
	bcs	11$
	INC KOLFIL
	MOV 20(R3),(R1)+
11$:	bic	#100000,22(r3)
	RTS	PC	
5$:	CLR (R1)+
	CLR (R1)+
	CLR (R1)+
	MOV R1,(PC)+
BMEM::	.WORD 0
	mov	dir,r3
	mov	30(r3),r4
	add	#500-30,r3
	MOV	#320,306
1$:	add	#30,r3
	cmpb	(r3),#377
	beq	1$
	JSR	R5,EXT
	.ASCIZ/PXF/
	BCS	5$
	MOV	R3,-(SP)
	MOV	R4,-(SP)
	MOV	#326,R1
	TST	(R3)+
	MOV	#14.,R2
3$:	MOVB	(R3)+,R0
	CMPB	R0,#56
	BEQ	2$
	MOVB	R0,(R1)+
	SOB	R2,3$
2$:	MOVB	R0,(R1)+
	MOVB	(R3)+,(R1)+
	MOVB	#'K,(R1)+
	MOVB	#'T,(R1)+
	CLRB	(R1)+
	SOB	R2,.-2
	MOV	DIR,R3
	CALL	@DIRFIN
	BCC	4$
	MOV	2(SP),R3
	SEC
	CALL	@DELETE
4$:	MOV	(SP)+,R4
	MOV	(SP)+,R3
5$:	SOB	R4,1$
	CALL	@SAVDIR
;------------------------------
	CLR TAREA
;	CLR TKMS	; Текущий мессаж
	JSR PC,MSCR	; Окно в европу...
	JSR PC,CPK	; Создать список
	JSR PC,SLMS	; Напечатать экран
MT1:	JSR PC,TARA	; Текущий пакет
KMEN:	JSR PC,DSKS

	JSR PC,KEY
	jsr	pc,@tst2
	MOV #HKEYS,R1
1$:	CMPB R0,(R1)+
	BEQ 2$
	TSTB (R1)
	BNE 1$
	BR KMEN
2$:	SUB #HKEYS+1,R1
	ASL R1
	JSR PC,@HPAD(R1)
	BR KMEN
HKEYS:	.BYTE 3,';,'-,32,33,'F,'S,40,12,10,31
	.BYTE 'M,'K,'A,'I
	.BYTE 0
	.EVEN; KT    ;      -     ╦    ╧
HPAD:	.WORD QEXIT,QAARE,QDARE,QPMSG,QNMSG
	.WORD QFRTO,QSUBJ,QRMSG,QRMSG,QRPMS,QRNMS
	.WORD QMODE,QKILL,QAREA,QINFO
;--------------------------------


;------ Создать каталог писем -----
UNAME:	JSR PC,NMTR
;	MOV TAREA,R0
;	ASL R0
;	MOV FREMEM+2000(R0),R0
	MOV #326,R1
	MOV #7.,R2
2$:	MOV (R0)+,(R1)+
	SOB R2,2$
	RTS PC
UNAM2:	MOV #326,R0
51$:	CMPB (R0)+,#'.
	BNE 51$
	INC R0
	MOVB #'X,(R0)+
	MOVB #'F,(R0)+
	MOV #320,R1
	MOV #40000,2(R1)
	RTS PC
LMSG::	.WORD 40006	; Начало списка сообщений

CPK::	JSR PC,UNAME
	JSR PC,UNAM2
	MOV #<3+20+10>,(R1)
	MOV #MMSG,177716
	EMT 36
	MOV #MQWK,177716
	TSTB 1(R1)
	BNE 52$
	RTS PC
;------ Не найден файлик... ----
52$:	JSR	PC,UNAME
	JSR	PC,DSKF
	MOV	300,FBLK
	MOV	302,LBLK
	BCC	1$
	JMP	100000	; Такого не бывает...
1$:	MOV	#-1,TKMS
	MOV	#-1,(PC)+
SSKB:	.WORD	0
	MOV	LMSG,(PC)+
EMSG:	.WORD	0
	CLR	(PC)+
TKB:	.WORD	0
	MOV	#72,(PC)+
TKO:	.WORD	0
	JSR	PC,LLLB
	MOV	#MMSG,177716
	CLR	40000
	MOV	36000+56,40002	; ORIG ZONE
	MOV	FBLK,40004
1$:	JSR	PC,LLLB
15$:	INC	TKMS
	MOV	TKO,R5
	CMP	R5,#1700
	BLO	16$
	SUB	#1000,TKO
	INC	TKB
	BR	1$
16$:	TSTB	36000(R5)
	BNE	47$
	TSTB	36001(R5)
	BEQ	4$
47$:	MOV	#MMSG,177716
	INC	40000	; Учет числа в арии

	MOV EMSG,R5
;	MOV #MMSG,177716
	MOV TKB,(R5)
	MOV TKO,2(R5)
49$:	CMP 2(R5),#1000
	BLO 48$
	INC (R5)
	SUB #1000,2(R5)
	BR 49$
48$:	ADD #4,R5
	MOV #MQWK,177716
	.ON
	MOV R5,EMSG
	MOV TKO,R3

	MOV #<7*2>,R5	; Заголовок
20$:	JSR PC,LRBT
	SOB R5,20$

	MOV #4,R5	; 4* ASCIZ
21$:	JSR PC,LRBT
	TSTB R0
	BNE 21$
	SOB R5,21$

	MOV #TXT10,R5	; Area
25$:	JSR PC,LRBT
	CMPB R0,(R5)+
	BNE 23$
	TSTB R0
	BEQ 24$
	TSTB (R5)
	BNE 25$
	CLR R5		; CRC
26$:	JSR PC,LRBT
	CMPB R0,#15
	BEQ 231$
	ADD R0,R5
	MOV R5,R0
	CLRB R0
	SWAB R0
	ADD R0,R5
	BR 26$
231$:	MOV #MMSG,177716
	MOV EMSG,R0
	SWAB R5
	BIC #777,R5
	BIS R5,-(R0)
	MOV #MQWK,177716
	MOV #1,R0

23$:	TSTB	R0
	BEQ	24$
	JSR	PC,LRBT
	BR	23$

24$:	MOV	R3,TKO
	MOV	#MQWK,177716
	JSR	PC,PMSG
	BR	1$

4$:	MOV	#MQWK,177716
	CLR	TKMS
	JSR	PC,PMSG

	MOV	#MMSG,177716
	MOV	EMSG,R0
	CLR	(R0)+
	CLR	(R0)+
	SUB	#40000,R0
	MOV	R0,324
	MOV	#40000,322
	JSR	PC,UNAM2
	MOV	#320,R1
	MOV	#<2+10+20>,(R1)
;------ EMT36 в мусор -----
EMUS::	MOV	SUBTEK,-(SP)
	MOV	(PC)+,R0
PDKT:	.WORD 0
	MOVB	R0,SUBTEK
	EMT	36
	MOV	(SP)+,SUBTEK
	MOV	#MQWK,177716
	JSR	PC,DSKS
	RTS PC
;------ Чтение байта ----
LRBT:	MOV R5,-(SP)
	MOVB 36000(R3),R0
	INC R3
	CMP R3,#2000
	BNE 1$
	MOV R0,-(SP)
	ADD #2,TKB
	JSR PC,LLLB
	MOV (SP)+,R0
	CLR R3
1$:	MOV (SP)+,R5
	RTS PC
;------ Чтение двух блоков ----
LLLB:	MOV TKB,R0
	CMP R0,SSKB
	BEQ 15$
	MOV R0,SSKB
	MOV #36000,R2
	MOV #1000,R1
;	MOV FBLK,R4
;	ADD LBLK,R4
;	CMP R0,R4
;	BHIS 4$
	EMT 364
	TSTB 52
	BEQ 15$
	MOV #MQWK,177716
	JMP 100000
15$:	RTS PC
;------ Декодирование десятичного числа ---
DC1:	INC R1
DECDEC::
	CLR R2
	CMPB (R1),#'9
	BHI DC1
	CMPB (R1),#'0
	BLO DC1
2$:	ASL R2		; R2*10.
	MOV R2,R0
	ASL R2
	ASL R2
	ADD R0,R2
	MOVB (R1)+,R0
	SUB #60,R0
	ADD R0,R2
	CMPB (R1),#'9
	BHI 1$
	CMPB (R1),#57
	BHI 2$
1$:	RTS PC
;------ Домой -----
QEXIT:	CLR 1000
	JMP 100000
;------ Увеличить # пакета ---
QAARE:	CMP TAREA,KOLFIL
	BEQ RT1
	JSR PC,SOUND
	INC TAREA
QA1::	JSR PC,CLKS
	JSR PC,TARA
	JSR PC,CLS
	JSR PC,CPK
QA2::	CLR TKMS
	JSR PC,SLMS
RT1:	RTS PC
;------ Уменьшить его же -----
QDARE:	TST TAREA
	BEQ RT1
	JSR PC,SOUND
	DEC TAREA
	BR QA1
;------ Взять # первого блока файла ----
DSKF::	MOV	#MQWK,177716
	MOV	DIR,R3
	JSR	PC,@DIRFIN	; Найти
	BCS	DS1
	TSTB	(R3)
	BMI	DS1
	ADD	#20,R3
	MOV	(R3)+,300
	MOV	(R3)+,302
DSKS::	.WORD 12700
DS1:	CLR R0
	MOV BLK,R3
	CLR (R3)
	MOV (R3),177130
	TST R0
	BNE 2$
	SEC
2$:	RTS PC
FBLK::	.WORD 0
LBLK:	.WORD 0
DSKR:	ADD FBLK,R0
	JMP @INOUT
;------ Информационная часть картинки -------
MSCR:	JSR R0,TBLK
	.WORD TXT4,42003
	.WORD TXT5,42203,170002
 	.WORD TXT2,42203,162203
	.BYTE 72,24

	.WORD TXT6,46202	; Окно терминала 
	.WORD 46402,46201,46276
	.WORD 76,47401,46401,<22*12>+4
	.WORD TXT7,76203,76202,76476
	.WORD 1,77476,77474,2
	.WORD 0

	RTS PC

;------ Текущий мессаг ----
PMSG::	MOV (PC)+,R1
TKMS::	.WORD 0
	MOV #<TXT8+1>,R2
	MOV #3,R3
	JSR PC,MDEC

2$:	JSR R0,TBLK
	.WORD TXT8,43446
;	.WORD 43455
;	.WORD 43464
	.WORD 0
	RTS PC
;------ Родить десятичное число. ------
MDEC::	CLR R5
	MOV #TDEC+12,R4
	SUB R3,R4
	SUB R3,R4
4$:	CLR R0
2$:	INC R0
	SUB (R4),R1
	BPL 2$
	ADD (R4)+,R1
	DEC R0
	BNE 5$
	TST R5
	BNE 5$
	CMP R3,#1
	BEQ 5$
	MOV #-20,R0
	BR 3$
5$:	MOV SP,R5
3$:	ADD #60,R0
	MOVB R0,(R2)+
	SOB R3,4$
	RTS PC
TDEC:	.WORD 10000.,1000.,100.,10.,1
;------ Выдать адрес по # ---
NMTR:	MOV (PC)+,R0
TAREA::	.WORD 0
	ASL	R0
	MOV	FREMEM+2000(R0),R0
	MOV	DIR,R1
	ADD	#500-30,R1
1$:	ADD	#30,R1
	CMP	20(R1),R0
	BNE	1$
	TST	22(R1)
	BEQ	1$
	MOV	R1,R0
	ADD	#2,R0
	RTS	PC
;------ Нарисовать текущую область -------
TARA2::	MOV #15,R0
	JSR PC,PRCHR
	MOV #TXT11,R5
	BR TAR1
TARA::	MOV #15,R0
	JSR PC,PRCHR
	JSR PC,NMTR
	MOV R0,R5
TAR1:	MOV #43422,R2
	MOV #16,R1
1$:	MOV R1,-(SP)
	MOVB (R5)+,R0
	MOV R5,-(SP)
	JSR PC,PRCHR
	MOV (SP)+,R5
	MOV (SP)+,R1
	SOB R1,1$
RT2:	RTS PC
;------ Печать строки 80 символов ----
;STR8:	MOVB (R5)+,R0
;	BEQ RT2
;	MOV R5,-(SP)
;	JSR PC,PRC8
;	MOV (SP)+,R5
;	INC R1
;	BR STR8
;------ Печать символа. R0 - Code, R1 - Address. ---
PRC8::	MOV R1,-(SP)
	bic #177400,r0
	mov	#112036,r2	;mov	#111576+217,r2

	movb	IBMBK(R0),R0
	cmpb	r0,#200
	blo	63$
	cmpb	r0,#240
	bhis	63$
	mov	#<fnt-1700+240>,R2		;-2400+740,r2

63$:	add	#-20,r0
	cmp	r0,#201
	blo	6$
	add	#340,r0
6$:	asl r0
	mov r0,r4
	asl r4
	asl r4
	add r4,r0
	add	r2,r0		;ADD #112036,R0
	MOV R1,R4
	BIC #177600,R4
	MOV R4,R3
	ASL R3
	ADD R3,R4

	MOV R1,R3
	ASR R4
	ASR R4
	ASL R3
	BIC #177771,R3
	BIC #177,R1
	ADD R4,R1
	ADD #2,R1	; Левое смещение
	MOV #12,R5
5$:	MOVB (R0)+,R2
	BIC #177700,R2
	ADD R3,PC
	BR 1$
	BR 4$
	BR 3$
	BR 2$
4$:	CLR R4
	.REPT 2
	ROR R2
	RORB R4
	.ENDR
	BICB #^B11000000,(R1)
	BICB #^B00001111,1(R1)
	BISB R4,(R1)
	BICB #177760,R2
	BISB R2,1(R1)
	BR 41$
2$:	BICB #^B11111100,(R1)
	CLC
	ASL R2
	ASL R2
	BISB R2,(R1)
	BR 41$
1$:	BICB #^B00111111,(R1)
	BISB R2,(R1)
	BR 41$
3$:	BICB #^B00000011,1(R1)
	BICB #^B11110000,(R1)
	MOV R2,R4
	ASL R4
	ASL R4
	ASL R4
	ASL R4
	BIC #17,R4
	BISB R4,(R1)
	ASR R2
	ASR R2
	ASR R2
	ASR R2
	BIC #177774,R2
	BISB R2,1(R1)
41$:	SUB #-100,R1
	SOB R5,5$
	MOV (SP)+,R1
	RTS PC
;------ Очистить кэш -----
CLKS::	MOV #MMEM,177716
	MOV #40000,R0
	MOV #200,R1
3$:	CLR (R0)
	DEC (R0)+
	SOB R1,3$
	MOV #MMSG,177716
	MOV #40000,R0
	MOV #4000,R1
31$:	.REPT 4
	CLR (R0)+
	.ENDR
	SOB R1,31$
	MOV #16200,177716
	RTS PC
;------ Чтение конфига арий --------
ADBEG=	22000
LAREA::	MOV #ARBLK,R1
	EMT 36
	MOV #ADBEG,R0
	TSTB 1(R1)
	BEQ 1$
	CLR (R0)
	RTS PC
1$:	MOV #ADBEG+2,R1
	CLRB (R0)+
6$:	CMPB (R1),#'%
	BEQ 7$
	CMPB (R1)+,#'+
	BNE 6$
	INC ADBEG
2$:	MOVB (R1)+,(R0)
	CMPB (R0)+,#40
	BNE 2$
	DEC R0
	CLRB (R0)+
3$:	CMPB (R1)+,#40
	BEQ 3$
	DEC R1
4$:	MOVB (R1)+,(R0)
	CMPB (R0)+,#37
	BHI 4$
	DEC R0
	CLRB (R0)+
	BR 6$
7$:	RTS PC
;------ Локальний инит ---
LINIT:	MOV #1$,10
	MOV #2$,20
	MOV #775$,SCREEN	; OUTPUT OFF
	IOT
	JSR PC,CLKS
	.WORD -1
775$:	RTS PC
1$:	CMP 14,#112064
	BNE 5$
	BIS #20,2(SP)
5$:	RTI
2$:	BIC #20,2(SP)
	RTI
;--- Поиск расширения файла ---
EXT::	MOV	R5,(SP)
	ADD	#4,@SP
4$:	Mov	r3,-(SP)		;CALL	EXT
	TST (R3)+		;.ASCIZ /PKT/
	MOV #11.,R2		;выход - бит C
7$:	CMPB (R3)+,#56
	BEQ 9$
	SOB R2,7$
	BR	8$
9$:	movb (r3)+,r0
	jsr pc,@tst2
	CMPB r0,(R5)+	;#'P
	BNE 8$
	movb (r3)+,r0
	jsr pc,@tst2
	CMPB r0,(R5)+	;#'K
	BNE 8$
	movb (r3)+,r0
	jsr pc,@tst2
	CMPB r0,(R5)+	;#'T
	BNE 8$
	tst	(pc)+
8$:	sec
	MOV	(SP)+,R3
	rts	pc

;------ Текстики ------
TXT0:	.BYTE 236,13,11
;	.ASCII/Copyright (c) 1995 by LAV corporation/
	.ASCII/  (C) 1995, 96  by LAV & MKT corp.   /
	.BYTE 1,203,13,12,204,205,206,0
	.BYTE 220,13,77,0
	.BYTE 2,207,203,13,75,211,0
TXT1:	.BYTE 214,216,13,75,215,0

TXT2:	.ASCIZ/PKT Reader v1.50 (c)1995 LAV & MKT /
;TXT2:	.ASCIZ/Здесь будет информация о пакете.../

TXT4:	.BYTE 2,217,13,71,0
TXT5:	.BYTE 1,40,13,71,14,0,7,5,3
	.ASCII/Текущий пакет: /<13><15.>/MSG: /<13><4>
	.ASCII/╠: /<13><4>/╬: /<13><9.>
	.BYTE 14,0,2,40,14,13,71,1,0
TXT6:	.BYTE 2,217,13,59.,0,1,40,13,59.,14,0
	.BYTE 2,213,0,212,0
TXT7:	.BYTE 14,0,217,217,13,58.,0,14,0
TXT8:	.ASCIZ<15>/LAV/
TXT91:	.WORD	3,0,0
TXT9:	.ASCII<177>/mycop        /
TXT10:	.ASCIZ/AREA:/
TXT11:	.ASCIZ/Tossed packet /
KLUJ:	.ASCIZ/@K: /
;	.ASCIZ<212>//<213><14>
;	.ASCIZ<212>//<213><14>
;	.ASCIZ<212>//<213><14>
;	.ASCIZ<212>//<213><14>
;	.ASCIZ<212>//<213><14>
;	.ASCIZ<212>//<213><14>

	.EVEN

;------ Таблица ALT ╬ КОИ-8 ---------
IBMBK2::
.byte	0,'@,'@,'╒,'╦,'╢,'╘,40
.byte	'╠,11,40,40,40,40,40,'*
.byte	'╬,'╠,'*,'!,240,'&,'╣,'*
.byte	'Ё,'╜,'╬,'╠,'L,'*,'Ё,40

ALTSTB::.BYTE 341,342,367,347,344,345,366,372	;200
	.BYTE 351,352,353,354,355,356,357,360	;210
	.BYTE 362,363,364,365,346,350,343,376	;220
	.BYTE 373,375,377,371,370,374,340,361	;230
	.BYTE 301,302,327,307,304,305,326,332	;240
	.BYTE 311,312,313,314,315,316,317,320	;250
	.BYTE 277,277,277,267,260,244,260,243	;260
	.BYTE 243,260,257,243,271,271,271,243	;270
	.BYTE 246,241,253,245,265,256,275,245	;300
	.BYTE 246,252,274,250,245,247,262,274	;310
	.BYTE 254,250,273,246,246,252,252,266	;320
	.BYTE 272,271,252,277,277,267,267,277	;330
	.BYTE 322,323,324,325,306,310,303,336	;340
	.BYTE 333,335,337,331,330,334,300,321	;350
	.BYTE 345,305,040,040,040,040,276,261	;360
	.BYTE 255,263,040,040,040,040,040,040	;370

IBMBK==.
.byte	0,216,216,'╒,'╦,'╢,'╘,7
.byte	30,11,0,0,0,15,0,'*
.byte	'╬,'╠,202,'!,240,223,210,'*
.byte	'Ё,'╜,'╬,'╠,'L,202,'Ё,40

.ascii	/ !"#$%&'()*+,-./<57>/0123456789:/<73>
.ASCII	/<=>?@ABCDEFGHIJKLMNOPQRSTUVWXYZ[\]^_`abcdefghijk/	;74-
.ASCII	/lmnopqrstuvwxyz{|}~/<177>
.ASCII	/АБВГДЕЖЗИЙКЛМНОПРСТУФХЦЧШЩЪЫЬЭЮ/		;200-237
.ASCII	/Яабвгдежзийклмноп©/<236><221>/╥╟╓/<220>	;200-267
.ASCII	<207><233><204>/╞/<203><231>/╧/<232>		;270-277
.ASCII	/ё╕║╚╔╣╝╫/<235><206><212><201><213><205>/╖/<222>;300-317
.ASCII	/╪╛╗╩╕/<226><214><225>/╤╨╧╙/<215><210><224><211>;320-337
.ascii	<230>/рстуфхцчшщъыьэюя=/	;
.ASCII	/е><╥╥/
.byte	200,217,234,227,227
.ascii	/RN$/<177>/ /
.EVEN


PRCNF:	.WORD 73,FREMEM,0
	.ASCII/PR.CNF          /
	.BLKB 26.

ARBLK:	.WORD 73,ADBEG+2,0
	.ASCII/AREAS.BBS       /
	.BLKB 26.
	.even


TSMM:.WORD	7700,1760,374,77
FNT:.WORD	0,10,76,10
.WORD	0,12024,173424,177400,0,0,0,63044
.WORD	63377,44,0,0,17400,13420,12024,12024
.WORD	12024,13424,13420,12024,12024,12024,172024,172004
.WORD	12024,12024,12024,172024,176004,0,0,0
.WORD	0,12037,12024,12024,0,0,177400,177777
.WORD	177777,170360,170360,170360,170360,170360,0,176000
.WORD	172004,12024,12024,0,177400,173400,12024,12024
.WORD	0,174000,174010,4010,4010,177777,177777,177777
.WORD	177777,177777,37000,52501,56501,40511,76,0
.WORD	14446,23000,31,0,12024,12024,12027,12024
.WORD	12024,10504,10504,10504
.WORD	10504,10504,12024,173424
.WORD	173400,12024,12024,11014
.WORD	6002,11022,10014,6022
.WORD	7417,7417,7417,7417
.WORD	7417,0,0,12374
.WORD	12024,12024,4010,174010
.WORD	174010,0,0,0
.WORD	16000,37076,16076,0
.WORD	177777,177777,377,0
.WORD	0,12024,13424,17420
.WORD	0,0,4010,7410
.WORD	7410,0,0,0
.WORD	7400,7410,4010,4010
.WORD	0,16000,21042,16042
.WORD	0,12024,12024,12364
.WORD	12024,12024,52652,52652
.WORD	52652,52652,52652,31714
.WORD	31714,31714,31714,31714

.END START