CLS$=56		SELP$=0		TAKE$=50	SWAP$=2
COLOR=446

	FONT=112276

	.WORD	51414
	MOV	(SP)+,RETR+2
	MOV	@#4,OLD4

SETUP:	TRAP	CLS$

	TRAP	SELP$
	TRAP	TAKE$
	TRAP	10		;TXTA$
	.WORD	40201	.ASCIZ/File: /	.EVEN

	EMT	246		;PRINA.

	MOV	#40000,@#202
	MOV	#2000,@#204
	MOV	#40000,@#206
	MOV	#36000,@#210

	MOV	#41500,R1
	MOV	#40,R2
1:	MOV	#52525,(R1)+
	SOB	R2,1
	TRAP	SELP$
	MOV	R3,NT
	MOV	R3,NK
	MOV	R3,KT
	MOVB	#12,(R3)+
	MOVB	#12,(R3)+
	CMPB	-(R3),-(R3)
	ADD	#7000,R3
	MOV	R3,KPM
	ADD	#1000,R3
	MOV	R3,PD+2
	ADD	#4,R3
	MOV	R3,NBL
	ADD	#500,R3
	MOV	R3,NMA
	ADD	#70,R3
	MOV	R3,KMA+2
	TRAP	SELP$
	TRAP	TAKE$
	MOV	#320,R1
	MOV	R1,R0
	MOV	#3,(R0)+
	MOV	NT,(R0)+
	CLR	(R0)+
	TST	(R3)+
	MOV	#16,R2
	MOVB	(R3)+,(R0)+
	SOB	R2,.-2
	MOV	PC,R0
	ADD	#WSE-.,R0
	MOV	R0,@#120074
	EMT	36
	TSTB	1(R1)
	BEQ	0OK
	JMP	OKON
0OK:	ADD	@#266,KT
	MOV	NT,R1
000:	CMP	R1,KT
	BHI	STA
	TSTB	(R1)+
	BNE	000
	MOVB	#12,-(R1)
	BR	000

STA:	MOV	PC,R5
	ADD	#NT-.,R5
	MOV	PC,R4
	ADD	#KT-.,R4
	MOV	NK,R3
	MOV	#776,SP
	MOV	PC,R0
	ADD	#STA-.,R0
	MOV	R0,@#4
	MOVB	#12,@0(R4)
	MOV	@R5,R0
	MOVB	#12,-(R0)
	CLR	PZB
	CALL	PN0
2:	MOV	KPM,KP
	CALL	PM0
	MOV	PC,R0
	ADD	#KX-.,R0
	MOV	#5,R5
1:	CLR	(R0)+
	SOB	R5,1


	CALL	TE0
	.WORD	TXG-.

M:	CALL	PD
01:	CALL	T4
	CALL	A
	BR	M

K34:	CALL	BUS
	MOV	R3,R4
	MOV	R3,R0
	BR	2
1:	INC	R0
2:	MOV	R0,R4
	MOV	NMO,R5
	CALL	P12
	BEQ	B01
	CMP	R4,KT
	BHIS	B01
0:	CMPB	(R4)+,(R5)+
	BNE	1
	CALL	P12
	BNE	0
	MOV	NK,R5
	CLR	R2
4:	CMP	#24,R2
	BMI	5
	CMP	R5,R4
	BHI	3
	CALL	C1
	CMPB	(R2)+,(R5)+
	BR	4
3:	CMPB	-(R2),-(R5)
	CALL	C3
	CLR	R1
	EMT	24
	MOV	R5,R3
	BR	6
5:	MOV	R4,R3
R00:	CALL	T10
	MOV	R3,-(SP)
	MOV	R5,NK
	CALL	US4
	MOV	(SP)+,R4
6:	CALL	K31
	CMP	R3,R4
	BLO	6
WSE:	RET
C8D:	CALL	CA
	INC	R2
C8C:	CMP	#27,R2
	BNE	C8D
	CALL	C8A
	BR	C84
C8:	EMT	26
	MOV	R2,-(SP)
	MOV	R3,-(SP)
	MOV	R1,-(SP)
0:	CALL	T24
	BHIS	C8C
	CMP	#27,R2
	BEQ	C81
	CALL	T6
	CALL	C1
	CALL	T26
	CMPB	(R5)+,(R2)+
	MOV	R5,R3
	BR	0
C81:	CALL	T6
C84:	MOV	(SP)+,R1
	MOV	(SP)+,R3
	MOV	(SP)+,R2
C86:	EMT	24
K3C:	CMP	#24,R2
	BLO	C88
	RET
C88:	MOV	NK,R5
	CALL	C1
	INC	R5
	MOV	R5,NK
	TST	(R2)+
	EMT	24
	CALL	T26
	MOV	R3,R5
	MOV	#3,R0
0:	CALL	C1
	INC	R5
	CMP	R5,KT
	BHIS	1
	SOB	R0,0
	CALL	C5
1:	MOV	#24,R2
	BR	C86
B00:	BR	K34
K30:	CALL	BUS
	CMP	R3,NT
	BEQ	B01
	CALL	K10
K26:	CMPB	@R3,#12
	BNE	0
	CALL	BUS
	CALL	T24
	BNE	1
B01:	CALL	JZW
1:	MOV	R3,R0
	MOV	R3,-(SP)
	INC	R3
2:	MOVB	(R3)+,(R0)+
	CMP	R0,KT
	BHI	03E
	MOVB	(R3)+,(R0)+
	CMP	R0,KT
	BLOS	2
03E:	MOV	(SP)+,R3
	DEC	KT
	CALL	T14
	BHIS	3
	DEC	MET
3:	BR	C8
0:	CALL	ZAB
	BVS	B01
	CALL	C7
JT6:	JMP	T6
K12:	CALL	BUS
	MOV	KT,R0
	INC	R0
	CMP	R0,KP
	BHIS	B01
	INC	KT
	MOV	R1,-(SP)
	MOV	R0,R1
	INC	R1
0:	MOVB	-(R0),-(R1)
	CMP	R0,R3
	BEQ	0EE
	MOVB	-(R0),-(R1)
	CMP	R0,R3
	BNE	0
0EE:	MOV	(SP)+,R1
	MOVB	#12,(R3)+
	CALL	CA
	ASL	R0
	CALL	EMT16
	EMT	26
	CALL	T6
	CALL	T14
	BHIS	C83
	INC	MET
	BR	C83
K23:	CALL	BUS
	CALL	CX
	BVS	B01
	MOV	R5,R3
K31:	CALL	BUS
	CALL	T24
	BEQ	B01
	MOVB	(R3)+,R0
	CALL	T22
C83:	MOV	R1,KX
	JMP	K3C
K24:	MOV	#11,R0
B:	CALL	C6
	BVS	B01
	MOVB	R0,(R3)+
	CALL	T22
C82:	MOV	R1,KX
	BR	JT6
K27:	MOVB	#40,R0
	CALL	B
	BR	K2A
K36:	CALL	T2
	CALL	K12
	BR	K10
A:	CMPB	R0,#224
	BNE	0A1
	MOV	R3,-(SP)
	MOV	R2,-(SP)
	TRAP	70
	MOV	(SP)+,R2
	MOV	(SP)+,R3
	CALL	EMT6
	BR	B
0A1:	CMPB	R0,#40
	BHIS	B
	CLR	-(SP)
	MOV	PC,R4
	ADD	#KE1-.,R4
0:	TSTB	@R4
	BNE	1
	JMP	JZW
1:	INC	@SP
	CMPB	R0,(R4)+
	BNE	0
	MOV	(SP)+,R4
	ASL	R4
	ADD	PC,R4
	ADD	#TABKEY-.-2,R4
	ADD	@R4,R4
	JMP	(R4)
K37:	CLR	MET
	TST	R1
	BNE	1$
	CALL	BUS
	MOV	R3,MET
A00:	RET
1$:	JMP	ZW
K10:	CALL	BUS
K2A:	CMP	R3,NK
	BEQ	K1D
	DEC	R3
	TST	R1
	BNE	K1A
	DEC	R2
CH:	CALL	C9
	MOV	R5,R3
K1N:	MOV	R4,R1
K1G:	EMT	24
K1M:	EMT	26
	BR	C83
K32:	CALL	BUS
	CALL	T10
	CMP	NT,R5
	BEQ	K1L
	MOV	KX,-(SP)
	CALL	T2
	CALL	K10
	MOV	(SP)+,KX
	CALL	CE
K3H:	MOV	R4,R1
	JMP	CD3
K1A:	MOVB	(R3),-(SP)
	MOVB	#12,@R3
	CALL	C9
	MOVB	(SP)+,@R3
	BR	K1N
K1D:	CMP	R3,NT
	BEQ	K1L
	DEC	R3
	MOV	#32,R0
	CALL	EMT16
	CALL	T10
	MOV	R5,NK
	CALL	C5
	BR	CH
K33:	CALL	BUS
	CALL	CX
	BVS	K1L
	MOV	R5,R3
	CMPB	(R3)+,(R2)+
	CALL	CE
	MOV	R5,R3
	MOV	R4,R1
	JMP	C86
K35:	CALL	BUS
	CALL	CX
	CMP	R5,KT
	BEQ	K1L
	CALL	T2
	CALL	CK
	JMP	K26
K1L:	CALL	JZW
K22:	BR	US
US4:	CALL	BUS
	MOV	NK,R3
US7:	MOV	#22,R0
	CALL	EMT16
	CLR	KX
	JMP	C8
US5:	EMT	26
	CALL	T2
	BR	K1M
P31:	BR	CH
P34:	CALL	TE
	.WORD	@TM
	EMT	26
	MOV	R1,-(SP)
	MOV	(PC)+,R5
NMO:	.WORD 500
	MOV	#34,R1
	MOV	#232,R0
	CALL	EMT16
0:	MOVB	#',R0
	EMT	22
	CALL	EMT6
	CMP	R0,#30
	BNE	1
	CMP	R5,NMO
	BEQ	0
	MOVB	#40,R0
	EMT	22
	CMPB	-(R5),-(R1)
	EMT	22
	BR	0
1:	CMP	#12,R0
	BNE	2
	MOVB	#40,R0
	EMT	22
	MOVB	#12,@R5
	MOV	(SP)+,R1
	EMT	24
	MOV	#232,R0
	CALL	EMT16
	RET
2:	CMPB	R0,#11
	BNE	3
	MOVB	R0,@R5
	MOVB	#40,R0
	BR	4
3:	CMPB	R0,#40
	BLO	0
	MOVB	R0,@R5
4:	EMT	22
	CMPB	(R5)+,(R1)+
	BR	0
P26:	CALL	CK
C8A:	MOV	#231,R0
	CALL	STIR
	RET
P30:	MOVB	(R3),-(SP)
	MOVB	#12,@R3
	CALL	T10
	MOV	R5,R3
	CALL	CK
	NEG	KUS
	MOVB	(SP)+,@R3
	CLR	R1
	EMT	24
	JMP	C82
US:	CALL	TE
	.WORD	@TXG
	CALL	BUS
	CALL	T4
	CALL	TE0
	.WORD	@TXG
USM:	CMPB	#37,R0
	BLO	US2
	CMPB	#10,R0
	BEQ	US5
	SUB	#26,R0
	BMI	K1L
	ASL	R0
	ADD	R0,PC
	BR	P26
	BR	P27
	BR	P30
	BR	P31
	BR	P32
	BR	P32
	BR	P34
	BR	P35
	BR	P36
PT:	TST	MET
	BEQ	4
P37:	MOV	MET,R3
	CALL	T10
	MOV	R5,R3
	MOV	R5,MET
P41:	MOV	R3,NK
	JMP	US4
P32:	MOV	#24,R4
0:	MOV	R4,-(SP)
	MOV	R0,-(SP)
	CMP	R0,#12
	BEQ	2
	CALL	K32
3:	BVS	1
	MOV	(SP)+,R0
	MOV	(SP)+,R4
	SOB	R4,0
4:	RET
1:	CMP	(SP)+,(SP)+
	RET
2:	CALL	K33
	BR	3
PU:	MOV	(PC)+,R5
P35:	CLR	R5
	MOV	MET,R4
	BEQ	P3A
	TST	R1
	BNE	P3A
	MOV	R3,R0
	SUB	R4,R0
	BLE	P3A
	TST	R5
	BNE	1
	MOV	KPM,R1
	SUB	KT,R1
	SUB	#1000,R1
	CMP	R0,R1
	BHIS	P3A
	MOV	R0,DBL
	MOV	(PC)+,R5
KPM:	.WORD	136000
	SUB	R0,R5
	MOV	R5,KP
	MOV	R4,R1
0:	MOVB	(R1)+,(R5)+
	SOB	R0,0
1:	MOV	R3,R5
	MOV	R4,R3
	CALL	CL
P00:	BR	P41
P36:	TST	R1
	BNE	P3A
	MOV	DBL,R4
	BEQ	P3A
	MOV	R4,R0
	MOV	KT,R5
	ADD	R5,R4
	CMP	R4,KP
	BHI	P3A
	CALL	T14
	BHIS	2
	ADD	DBL,MET
2:	MOV	R4,KT
	CMPB	(R4)+,(R5)+
0:	MOVB	-(R5),-(R4)
	CMP	R3,R5
	BNE	0
	MOV	KP,R5
	MOV	R3,R4
1:	MOVB	(R5)+,(R4)+
	SOB	R0,1
	BR	P41
P27:	BR	CN
US2:	MOV	PC,R4
	ADD	#TXH-.,R4
	MOV	R4,R5
	BIC	#240,R0
0:	TSTB	@R4
	BEQ	P3A
	CMPB	R0,(R4)+
	BNE	0
	SUB	R5,R4
	ASL	R4
	ADD	PC,R4
	ADD	#TABGLD-.-2,R4
	ADD	@R4,R4
	JMP	(R4)
PN:	MOV	NT,R3
PN0:	BR	P00
PD:	MOV	#137000,R4
	SUB	KT,R4
	JMP	CM
PK:	MOV	KT,R3
	MOV	#12,R0
0:	CALL	T10
	CMP	R5,NT
	BEQ	P00
	DEC	R5
	MOV	R5,R3
	SOB	R0,0
	INC	R3
	BR	PN0
P3A:	CALL	JZW
CN:	MOV	(PC)+,R4
NBL:	.WORD 137004
	MOV	KUS,R0
	BEQ	P3A
	BPL	7
	NEG	R0
7:	DEC	R0
	BEQ	P3A
	MOV	R0,R5
	ADD	KT,R0
	CMP	KP,R0
	BLO	P3A
	CALL	T14
	BHIS	8
	ADD	R5,MET
8:	MOV	R5,-(SP)
	MOV	KT,R5
	MOV	R0,KT
	CMPB	(R5)+,(R0)+
1:	MOVB	-(R5),-(R0)
	CMP	R5,R3
	BNE	1
	MOV	@SP,R0
2:	MOVB	(R4)+,(R5)+
	SOB	R0,2
	CALL	T6
6:	MOV	(SP)+,R0
	TST	KUS
	BPL	4
5:	MOV	R0,-(SP)
	CALL	K31
	MOV	(SP)+,R0
	SOB	R0,5
4:	RET
PM:	CALL	TE
	.WORD	@TXM
	INC	INM
PM0:	MOV	NMA,R0
	MOV	R0,BUM
	CLR	@R0
	RET
PI:	TST	INM
	BNE	2
	MOV	(PC)+,R4
NMA:	.WORD 137700
1:	MOVB	(R4)+,R0
	BEQ	0
	CMPB	R0,#23
	BNE	3
	MOVB	(R4)+,R0
	MOV	R4,-(SP)
	CALL	BUS
	CALL	USM
	BR	4
3:	MOV	R4,-(SP)
	CALL	A
4:	BVS	PI0
	MOV	(SP)+,R4
	BR	1
PI0:	TST	(SP)+
2:	SEV
0:	RET
PO:	MOV	BUM,R4
	CLRB	-2(R4)
PO0:	CLR	INM
	RET
PP:	CALL	TE
	.WORD	@TXR
	CLR	R4
	MOV	SP,R2
	MOV	#34,R1
0:	MOVB	#',R0
	EMT	22
	CALL	EMT6
	CMPB	R0,#'0
	BLO	3
	CMPB	R0,#'9
	BHI	0
	EMT	22
	INC	R1
	MOV	R4,-(SP)
	ASL	R4
	MOV	R4,-(SP)
	ASL	R4
	ASL	R4
	ADD	(SP)+,R4
	SUB	#'0,R0
	ADD	R0,R4
	BR	0
1:	CMP	R2,SP
	BEQ	0
	MOV	(SP)+,R4
	MOV	#40,R0
	EMT	22
	DEC	R1
	EMT	22
	BR	0
3:	CMP	R0,#30
	BEQ	1
	CMP	R0,#12
	BNE	0
	MOV	R2,SP
	MOV	#40,R0
	EMT	22
	TST	R4
	BEQ	5
4:	MOV	R4,-(SP)
	EMT	26
	CALL	PI
	BVS	PI0
	MOV	(SP)+,R4
	SOB	R4,4
5:
	CALL	TE0
	.WORD	@TXR
	RET
T4:	MOV	#232,R0
	CALL	EMT16
	CLRB	@#105
	MOV	#30000,R0
	TST	INN
	BEQ	5
	MOV	#1400,R0
5:	BIT	#100,@#177716
	BEQ	6
	CLR	INN
	BR	1$
6:	SOB	R0,5
	INC	INN
	INCB	@#105
1$:	MOV	#232,R0
	CALL	EMT16
4:	CALL	EMT6
	CMPB	R0,#224
	BEQ	1
	CMPB	R0,#200
	BLO	1
	CMPB	R0,#240
	BLO	4
1:	TST	INM
	BEQ	2
	MOV	BUM,R4
KMA:	CMP	R4,#137777
	BNE	3
	CLRB	@R4
	JMP	PO0
3:	MOVB	R0,@R4
	INC	BUM
2:	EMT	26
	RET
T2:	CALL	T10
	CLR	R1
CD3:	MOV	R5,R3
	EMT	24
	RET
CE:	MOV	(PC)+,-(SP)
C9:	CLR	-(SP)
	CALL	T10
	CLR	R4
	MOV	(PC)+,-(SP)
LENL:	.WORD	63.
2:	CALL	P12
	BEQ	4
	TST	2(SP)
	BNE	3
	CMP	R4,@SP
	BLO	1
4:	CMP	(SP)+,(SP)+
	RET
3:	CMP	KX,R4
	BLOS	4
1:	CMPB	(R5)+,#11
	BEQ	0
	INC	R4
	BR	2
0:	BIC	#7,R4
	ADD	#10,R4
	CMP	R4,@SP
	BLO	2
	MOV	(SP)+,R4
	TST	(SP)+
	RET
C7:	MOV	R3,R4
0:	MOVB	1(R4),(R4)+
	CMP	R4,KBS
	BLOS	0
	DEC	KBS
	RET
C6:	CALL	ZAB
	BVS	C71$
	CMP	KBS,KP
	BHIS	C71$
	INC	KBS
	MOV	KBS,R4
0:	MOVB	-(R4),1(R4)
	CMP	R4,R3
	BHI	0
	RET
ZAB:	TST	PZB
	BNE	1
	CALL	T10
	MOV	R5,NTS
	MOV	KT,R4
	ADD	#400,R4
	CMP	R4,KP
	BHIS	C71$
	MOV	R4,-(SP)
	ADD	#400,@SP
	CMP	(SP)+,KP
	BHI	C71$
	MOVB	#12,-(R4)
	INC	R4
	MOV	R4,NBS
	MOV	R3,-(SP)
	SUB	R5,@SP
	CALL	C60
	BVC	2
	TST	(SP)+
	CALL	JZW
2:	MOV	R4,KBS
	MOV	R5,KTS
	MOV	NBS,R3
	ADD	(SP)+,R3
	INC	PZB
1:	RET
C71$:	BR	C71
BUS:	TST	PZB
	BEQ	0
	MOV	R4,-(SP)
	MOV	R3,-(SP)
	MOV	KTS,-(SP)
	SUB	NTS,@SP
	MOV	KBS,R5
	SUB	NBS,R5
	SUB	(SP)+,R5
	BLE	1
	MOV	KT,R3
	MOV	R3,R4
	ADD	R5,R4
	MOV	R4,KT
2:	MOVB	@R3,@R4
	CMP	R3,KTS
	BEQ	5
	CMPB	-(R3),-(R4)
	BR	2
5:	MOV	R4,KTS
1:	MOV	R5,-(SP)
	MOV	NTS,R4
	MOV	NBS,R5
	CALL	C60
	MOV	KTS,R5
	CMP	R4,R5
	BEQ	4
3:	MOVB	(R5)+,(R4)+
	CMP	KT,R5
	BHIS	3
	DEC	R4
	MOV	R4,KT
4:	MOV	(SP)+,R5
	CLR	PZB
	SUB	NBS,@SP
	MOV	(SP)+,R3
	ADD	NTS,R3
	MOV	(SP)+,R4
	CALL	T14
	BHIS	0
	ADD	R5,MET
0:	RET
C60:	MOV	R0,-(SP)
	MOV	#400,R0
0:	CALL	P12
	BEQ	2
	MOVB	(R5)+,(R4)+
	SOB	R0,0
	MOV	(SP)+,R0
C71:	SEV
	RET
2:	MOVB	@R5,@R4
	MOV	(SP)+,R0
	RET
CK:	MOV	R3,R4
	CLR	KUS
	CALL	CX
	MOV	NBL,R0
0:	MOVB	(R4)+,(R0)+
	INC	KUS
	CMP	R4,R5
	BLOS	0
CL:	CALL	T14
	BHIS	1
	MOV	KUS,R4
	DEC	R4
	SUB	R4,MET
1:	MOV	R3,R4
0:	MOVB	(R5)+,(R4)+
	CMP	R5,KT
	BLOS	0
	DEC	R4
	MOV	R4,KT
	RET
T6:	MOV	R3,R5
C5:	MOV	R1,-(SP)
	MOV	R2,-(SP)
1:	CALL	P12
	BEQ	2
	MOVB	(R5)+,R0
	CALL	T22
	BVC	1
2:	CALL	C8A
	MOV	(SP)+,R2
	MOV	(SP)+,R1
	EMT	24
	RET
T10:	MOV	R3,R5
C3:	MOV	#-1,-(SP)
C10:	ADD	@SP,R5
	BR	C11
CX:	MOV	R3,R5
C1:	MOV	#1,-(SP)
C11:	CALL	P12
	BNE	C10
	TST	(SP)+
	BMI	0
	CMP	R5,KT
	BEQ	ZW0
	CLV
	RET
0:	INC	R5
	RET
T22:	CMP	R0,#12
	BEQ	5
	EMT	26
	MOV	LENL,R2
0:	CMP	R1,R2
	BHIS	2
	CMP	R0,#11
	BNE	1
	MOV	R0,-(SP)
3:	MOV	#40,R0
	CALL	T22
	BVS	OT0
	BIT	#7,R1
	BNE	3
	BR	OT0
1:	MOV	R0,-(SP)
	BIC	#177200,@SP
	CMP	(SP)+,#40
	BHIS	5
	COMB	@#45
	ADD	#100,R0
5:	CALL	EMT16
	EMT	26
	CLRB	@#45
	RET
2:	EMT	26
	BR	ZW0
CM:	MOV	R0,-(SP)
	MOV	R2,-(SP)
	MOV	R1,-(SP)
	MOV	#62,R1
	CLR	R0
	ROL	R4
	ROL	R0
	ADD	#60,R0
	EMT	22
	INC	R1
	MOV	#5,R2
1:	CLR	R0
	MOV	#3,R5
2:	ROL	R4
	ROL	R0
	SOB	R5,2
	CMP	R2,#1
	BEQ	0
	TST	R0
	BNE	0
	CMP	R1,#27
	BEQ	4
0:	ADD	#60,R0
	EMT	22
	INC	R1
4:	SOB	R2,1
	MOV	(SP)+,R1
	MOV	(SP)+,R2
OT0:	MOV	(SP)+,R0
	RET
CA:	CALL	C8A
T26:	MOV	#12,R0
	BR	C94
CLR:	MOV	#14,R0
C94:	CALL	EMT16
	RET
JZW:	TST	(SP)+
ZW:	MOV	R5,-(SP)
	MOV	#100,R5
	MOV	R5,R0
	MOV	R5,R1
1:	MOV	R0,R4
	BIS	R5,@#177716
0:	SOB	R4,0
	BIC	R5,@#177716
	MOV	R0,R4
2:	SOB	R4,2
	SOB	R1,1
	MOV	(SP)+,R5
ZW0:	SEV
	RET
T24:	CMP	R3,KT
	RET
T14:	CMP	R3,MET
	RET
TE:	MOV	@SP,R5
	ADD	@R5,R5
	MOV	R0,-(SP)
	MOVB	(R5)+,R1
	BR	2
1:	INC	R1
	EMT	22
2:	MOVB	(R5)+,R0
	BNE	1
T00:	MOV	(SP)+,R0
	BR	0
TE0:	MOV	@SP,R5
	ADD	@R5,R5
	MOV	R0,-(SP)
	MOVB	(R5)+,R1
1:	MOVB	#40,R0
	INC	R1
	EMT	22
	TSTB	(R5)+
	BNE	1
	BR	T00
TEX:	MOV	@SP,R1
	ADD	(R1),R1
	CLR	R2
	CALL	EMT20
0:	ADD	#2,@SP
	EMT	26
	RET
P12:	CMPB	@R5,#12
	RET

EMT16:	CMPB	R0,#231
	BNE	4
STIR:	MOV	R0,-(SP)
	MOV	R1,-(SP)
	MOV	R2,-(SP)
	MOV	R3,-(SP)
	MOV	R4,-(SP)
	MOV	R5,-(SP)
	MOV	@#160,R3
	MOV	R3,R1
	ADD	#1200,R1
	BPL	0OK
	CALL	@#102234
	BR	0EX
0OK:	MOV	R3,R1
	BIC	#177700,R3
	MOV	R3,R2
	MOV	#100,R0
	SUB	R0,R3
	NEG	R3
	MOV	R1,R5
	ADD	R0,R5
	ADD	R2,R0
	MOV	#5,R4
1:	MOV	R3,R2
2:	CLRB	(R1)+
	CLRB	(R5)+
	SOB	R2,2
	ADD	R0,R1
	ADD	R0,R5
	SOB	R4,1
0EX:	MOV	(SP)+,R5
	MOV	(SP)+,R4
	MOV	(SP)+,R3
	MOV	(SP)+,R2
	MOV	(SP)+,R1
	MOV	(SP)+,R0
	RET
4:	CMPB	R0,#232
	BNE	5
	JMP	KURSOR
5:	CMPB	R0,#40
	BLO	EM3
	CMPB	R0,#200
	BLO	TTOUT
	CMPB	R0,#240
	BHI	TTOUT
	RET
EM3:	MOV	R5,-(SP)
	CALL	@#102234
	MOV	(SP)+,R5
	RET

TTOUT:	MOV	R0,-(SP)
	MOV	R1,-(SP)
	MOV	R2,-(SP)
	MOV	R3,-(SP)
	MOV	R4,-(SP)
	MOV	R5,-(SP)
	BIC	#177400,R0
	TSTB	R0
	BPL	10
	SUB	#40,R0
10:	ASL	R0
	MOV	R0,R3
	ASL	R0
	ASL	R0
	ADD	R3,R0
	ADD	#112276-500,R0
	MOV	@#160,R3
	MOV	#100,R1
	MOVB	@#COLOR,R5
	BEQ	0NC
	CMP	R0,#112276
	BEQ	0NC
	MOV	#5,R2
4I:	MOVB	(R0)+,R4
	MOVB	R4,@R3
	RORB	R4
	BISB	R4,@R3
	BICB	R5,@R3
	ADD	R1,R3
	BPL	111
	SUB	#40000,R3
111:	MOVB	(R0)+,R4
	MOVB	R4,@R3
	RORB	R4
	BISB	R4,@R3
	BICB	R5,@R3
	ADD	R1,R3
	BPL	112
	SUB	#40000,R3
112:	SOB	R2,4I
	BR	20
0NC:	MOV	#5,R2
1NC:	MOVB	(R0)+,@R3
	ADD	R1,R3
	BPL	113
	SUB	#40000,R3
113:	MOVB	(R0)+,@R3
	ADD	R1,R3
	BPL	114
	SUB	#40000,R3
114:	SOB	R2,1NC
20:	TSTB	@#45
	BEQ	161
	MOV	@#160,R3
	MOV	#12,R2
163:	COMB	@R3
	ADD	#100,R3
	BPL	162
	SUB	#40000,R3
162:	SOB	R2,163
161:	INC	@#160
	INC	@#156
30:	MOV	(SP)+,R5
	MOV	(SP)+,R4
	MOV	(SP)+,R3
	MOV	(SP)+,R2
	MOV	(SP)+,R1
	MOV	(SP)+,R0
	RET

EMT6:	CALL	KURSOR
	CLR	@#177660
	CALL	@#101010
	COM	@#177660
KURSOR:	MOV	R3,-(SP)
	MOV	R2,-(SP)
	MOV	@#160,R3
	ADD	#600,R3
	MOV	#3,R2
1:	CALL	@#111434
	COMB	@R3
	SOB	R2,1
	MOV	(SP)+,R2
	MOV	(SP)+,R3
	RET

EMT20:	MOV	R0,-(SP)
	MOV	R3,-(SP)
	MOV	R2,R3
	SWAB	R3
	BIC	#177400,R2
1:	MOVB	(R1)+,R0
	CALL	EMT16
	CMPB	R0,R3
	BEQ	2
	SOB	R2,1
2:	MOV	(SP)+,R3
	MOV	(SP)+,R0
	RET
EXIT1:	CALL	BUS
	CALL	T10
	CLR	@#104
	MOV	OLD4,@#4
	TRAP	CLS$
	MOV	#1330,@#177664
	CLR	@#177660
	MOV	#50020,R0
	COM	@#44
	TRAP	30	;WIN$
	.BYTE	40,50
	TRAP	10	.WORD	51033	;TXTA$
	.ASCIZ/Save file:/	.EVEN
	TRAP	10	.WORD	51033+2700-4
	.ASCIZ<237>/(push KT for quit)/	.EVEN
	CLR	@#44
1R:	MOV	#51033+1400-2,@#160
	MOV	#326,R3
	MOV	#16,R2
	TRAP	36	;STR$
	BCS	OKON
	CMPB	@#326,#40
	BLOS	1R
	CMPB	@#327,#':
	BEQ	1R
	CMPB	@#326,#177
	BEQ	1R
	MOV	#230,@#177664
	TRAP	CLS$
	MOV	NT,R1
	MOV	#40000,R3
	MOV	KT,R2
	SUB	R1,R2
	TST	R2
	BNE	1177
	TST	(R2)+
1177:	MOV	R2,R0
	MOVB	(R1)+,(R3)+
	SOB	R0,.-2
	MOV	#320,R1
	MOV	R1,R0
	MOV	#2,(R0)+
	MOV	#40000,(R0)+
	MOV	R2,(R0)+
	MOV	@#120124,-(SP)
	CLRB	@#120124
	EMT	36
	TSTB	1(R1)
	BEQ	OKAI
	TRAP	70	;ZWUK$
12:	BIT	#100,@#177716
	BNE	12
	MOV	#320,R1
	EMT	36
OKAI:	MOV	(SP)+,@#120124
OKON:	MOV	(PC)+,R0
OLD4:	.WORD	0
	MOV	R0,@#4
	TRAP	CLS$
	MOV	#1330,@#177664

	MOV	#40000,@#202
	MOV	#2000,@#204
	MOV	#40000,@#206
	MOV	#36000,@#210

	CLR	@#177660
	CLR	@#120074
RETR:	JMP	@#0

NT:	.WORD	0
KT:	.WORD	0
KX:	.WORD	0
DBL:	.WORD	0
INM:	.WORD	0
MET:	.WORD	0
KUS:	.WORD	0
WOZ:	.WORD	0
INN:	.WORD	0
NK:	.WORD	0
BUM:	.WORD	0
PZB:	.WORD	0
NTS:	.WORD	0
KP:	.WORD	0
KTS:	.WORD	0
NBS:	.WORD	0
KBS:	.WORD	0
TABKEY:	.WORD	K24-.,K10-.,K12-.,K22-.,K22-.,K24-.,A00-.
	.WORD	K26-.,K27-.,K30-.,K31-.,K32-.
	.WORD	K33-.,B00-.,K35-.,K36-.,K37-.
TABGLD:	.WORD	EXIT1-.,P35-.,P36-.,PT-.,P34-.,PU-.,PI-.
.WORD	PM-.,PO-.,PK-.
	.WORD	PP-.,PN-.
TM:	.ASCIZ<24>/Модель:/
TXG:	.ASCIZ<24>/Префикс//  //  //  //  //  /
TXH:	.BYTE	'E
	.BYTE	'B
	.BYTE	'W
	.BYTE	'T
	.BYTE	'D
	.BYTE	'U
	.BYTE	'I
	.BYTE	'M
	.BYTE	'O
	.BYTE	'K
	.BYTE	'P
	.BYTE	'N
TXM:	.ASCIZ<25>/Макро/
TXR:	.ASCIZ<24>/Повтор:  // /
TX9:	.BYTE 14,0
KE1:	.BYTE	11,10
	.BYTE	12,23
	.BYTE	3,24
	.BYTE	25,26
	.BYTE	27,30
	.BYTE	31,32
	.BYTE	33,7
	.BYTE	2,36
	.BYTE	14,0
.EVEN
EOF:.EVEN
.END